c39e0217aa
Changes since version 1.34.1: * misc: adjust stalebot deadlines (Jameson Nash) * test: fix env-vars flakiness (cjihrig) * test: avoid truncating output lines (Jameson Nash) * darwin: stop calling SetApplicationIsDaemon() (Ben Noordhuis) * ibmi: implement uv_interface_addresses() (Xu Meng) * osx,fsevent: fix race during uv_loop_close (Jameson Nash) * osx,fsevent: clear pointer when deleting it [NFCI] (Jameson Nash) * Revert "aix: replace ECONNRESET with EOF if already closed" (Jameson Nash) * unix: handle uv__open_cloexec return value correctly (Anna Henningsen) -----BEGIN PGP SIGNATURE----- Comment: GPGTools - https://gpgtools.org iQIzBAABCgAdFiEElK42Z1xGTWS6+mjddDQ5C9vpucUFAl4pq5MACgkQdDQ5C9vp ucWJxA//fZm/u46gxSeRdWeFu9W1r1CgkJqmWT6vHeeBphk28lAulHAO0AM/bbbd x2WsLS8q7cLk3chwpN4CgJkgS8acqcsuHBGEzqc8o5cd76rCkua7eHvOR83D4Ix4 c46hJH7WF3S4jnVV09iAU+mGplyUPF3F8HvmbTNZnbsuLKj2U88kDjm4nsxiSwdn aMeyZNtM6NdtqHRgIup+SqS4hNvaUt+gD7715efTlGPDwLR3KCJ8Mzd9F4JFrPrT wCjAGLiTFZXFcnwR/Ysx66jQNjfp/fZy7G/zU+7UFKwCjZdwZyybqzy4lmYXtV7N 2hmliaxm3UsYPSD06mA+iUTdD9vnk2/htCNL5OBS11b6lAliYtdNC3l9BQ2Y3TVp xobPcjiRWmvN5P0GIL9/DjK7nxpSdj7BFFyyVz21/+OsYX+NYI4L/Vb4RjezGeGy RMS26S530fOsPCbPlSyEUqvjbTHI95FiLK8Y008YlRRsWVsCxrdrhDjT964LHZ51 nFFPkR0Ghr/y0d9AzBsrsnjAi9g/K+dX3F72S8S2gS3LMkLVr6fLrEQ5AmclAa4f 62TZvnKY3MzjdzsBpslGHHVp3l+HsNdkI27bLCbYUAL/c+R0fl96mac34IHGL+KV b/99O3WMxGtq/Zdn709ryMOLnC+F5KTJpl2LckExfxvubPcu9UQ= =SjB7 -----END PGP SIGNATURE----- Merge tag 'v1.34.2' into merge_1.34.2 PR-URL: https://github.com/libuv/libuv/pull/2649 Reviewed-By: Saúl Ibarra Corretgé <saghul@gmail.com>
83 lines
3.9 KiB
Plaintext
83 lines
3.9 KiB
Plaintext
# Copyright (c) 2013, Ben Noordhuis <info@bnoordhuis.nl>
|
|
#
|
|
# Permission to use, copy, modify, and/or distribute this software for any
|
|
# purpose with or without fee is hereby granted, provided that the above
|
|
# copyright notice and this permission notice appear in all copies.
|
|
#
|
|
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
|
|
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
|
|
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
|
|
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
|
|
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
|
|
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
|
|
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
|
|
|
|
AC_PREREQ(2.57)
|
|
AC_INIT([libuv], [2.0.0], [https://github.com/libuv/libuv/issues])
|
|
AC_CONFIG_MACRO_DIR([m4])
|
|
m4_include([m4/libuv-extra-automake-flags.m4])
|
|
m4_include([m4/as_case.m4])
|
|
m4_include([m4/libuv-check-flags.m4])
|
|
AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects] UV_EXTRA_AUTOMAKE_FLAGS)
|
|
AC_CANONICAL_HOST
|
|
AC_ENABLE_SHARED
|
|
AC_ENABLE_STATIC
|
|
AC_PROG_CC
|
|
AM_PROG_CC_C_O
|
|
CC_FLAG_VISIBILITY #[-fvisibility=hidden]
|
|
CC_CHECK_CFLAGS_APPEND([-g])
|
|
CC_CHECK_CFLAGS_APPEND([-std=gnu99])
|
|
CC_CHECK_CFLAGS_APPEND([-Wall])
|
|
CC_CHECK_CFLAGS_APPEND([-Wextra])
|
|
CC_CHECK_CFLAGS_APPEND([-Wno-long-long])
|
|
CC_CHECK_CFLAGS_APPEND([-Wno-unused-parameter])
|
|
CC_CHECK_CFLAGS_APPEND([-Wstrict-prototypes])
|
|
# AM_PROG_AR is not available in automake v0.11 but it's essential in v0.12.
|
|
m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
|
|
# autoconf complains if AC_PROG_LIBTOOL precedes AM_PROG_AR.
|
|
AC_PROG_LIBTOOL
|
|
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
|
|
LT_INIT
|
|
# TODO(bnoordhuis) Check for -pthread vs. -pthreads
|
|
AC_CHECK_LIB([dl], [dlopen])
|
|
AC_CHECK_LIB([kstat], [kstat_lookup])
|
|
AC_CHECK_LIB([nsl], [gethostbyname])
|
|
AC_CHECK_LIB([perfstat], [perfstat_cpu])
|
|
AC_CHECK_LIB([pthread], [pthread_mutex_init])
|
|
AC_CHECK_LIB([rt], [clock_gettime])
|
|
AC_CHECK_LIB([sendfile], [sendfile])
|
|
AC_CHECK_LIB([socket], [socket])
|
|
AC_SYS_LARGEFILE
|
|
AM_CONDITIONAL([AIX], [AS_CASE([$host_os],[aix*], [true], [false])])
|
|
AM_CONDITIONAL([ANDROID], [AS_CASE([$host_os],[linux-android*],[true], [false])])
|
|
AM_CONDITIONAL([CYGWIN], [AS_CASE([$host_os],[cygwin*], [true], [false])])
|
|
AM_CONDITIONAL([DARWIN], [AS_CASE([$host_os],[darwin*], [true], [false])])
|
|
AM_CONDITIONAL([DRAGONFLY],[AS_CASE([$host_os],[dragonfly*], [true], [false])])
|
|
AM_CONDITIONAL([FREEBSD], [AS_CASE([$host_os],[*freebsd*], [true], [false])])
|
|
AM_CONDITIONAL([HAIKU], [AS_CASE([$host_os],[haiku], [true], [false])])
|
|
AM_CONDITIONAL([HURD], [AS_CASE([$host_os],[gnu*], [true], [false])])
|
|
AM_CONDITIONAL([LINUX], [AS_CASE([$host_os],[linux*], [true], [false])])
|
|
AM_CONDITIONAL([MSYS], [AS_CASE([$host_os],[msys*], [true], [false])])
|
|
AM_CONDITIONAL([NETBSD], [AS_CASE([$host_os],[netbsd*], [true], [false])])
|
|
AM_CONDITIONAL([OPENBSD], [AS_CASE([$host_os],[openbsd*], [true], [false])])
|
|
AM_CONDITIONAL([OS390], [AS_CASE([$host_os],[openedition*], [true], [false])])
|
|
AM_CONDITIONAL([OS400], [AS_CASE([$host_os],[os400], [true], [false])])
|
|
AM_CONDITIONAL([SUNOS], [AS_CASE([$host_os],[solaris*], [true], [false])])
|
|
AM_CONDITIONAL([WINNT], [AS_CASE([$host_os],[mingw*], [true], [false])])
|
|
AS_CASE([$host_os],[mingw*], [
|
|
LIBS="$LIBS -lws2_32 -lpsapi -liphlpapi -lshell32 -lsecur32 -luserenv -luser32"
|
|
])
|
|
AS_CASE([$host_os], [netbsd*], [AC_CHECK_LIB([kvm], [kvm_open])])
|
|
AS_CASE([$host_os], [kfreebsd*], [
|
|
LIBS="$LIBS -lfreebsd-glue"
|
|
])
|
|
AS_CASE([$host_os], [haiku], [
|
|
LIBS="$LIBS -lnetwork"
|
|
])
|
|
AC_CHECK_HEADERS([sys/ahafs_evProds.h])
|
|
AC_CONFIG_FILES([Makefile libuv.pc])
|
|
AC_CONFIG_LINKS([test/fixtures/empty_file:test/fixtures/empty_file])
|
|
AC_CONFIG_LINKS([test/fixtures/load_error.node:test/fixtures/load_error.node])
|
|
AC_CONFIG_LINKS([test/fixtures/lorem_ipsum.txt:test/fixtures/lorem_ipsum.txt])
|
|
AC_OUTPUT
|