f66af623cf
Extend `INSTALL-CMAKE` document with the list of available options, a short description and default values. The list may not be 100% complete. There are no component boundaries in CMake, so the line is blurry between curl options, CMake options, CMake Find modules options. I included certain CMake options that seemed useful, and/or have dedicated use withing curl's CMake source. But, all CMake built-in options are usable, as documented upstream in CMake. The naming of the options has a heritage and the inconsistencies with it, including a lack of clear namespace. This may be subject to future updates, also after figuring out which name has special meaning within CMake and/or CMake projects out of unwritten convention or something more tangible. CMake allows to initialize any internal variable via `-D`. This may be useful to pre-initialize/override feature check results. The list doesn't contain these, and they remain officially undocumented. Also: - make adjustments to keep the spellchecker happy. - retrofit description changes to the cmake sources. - stop documenting deprecated `Find*` variables. Reported-by: Daniel Stenberg Fixes https://github.com/curl/curl/discussions/14885 Closes #15388
65 lines
2.3 KiB
CMake
65 lines
2.3 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the wolfSSH library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `WOLFSSH_INCLUDE_DIR`: The wolfSSH include directory.
|
|
# - `WOLFSSH_LIBRARY`: Path to `wolfssh` library.
|
|
#
|
|
# Result variables:
|
|
#
|
|
# - `WOLFSSH_FOUND`: System has wolfSSH.
|
|
# - `WOLFSSH_INCLUDE_DIRS`: The wolfSSH include directories.
|
|
# - `WOLFSSH_LIBRARIES`: The wolfSSH library names.
|
|
# - `WOLFSSH_VERSION`: Version of wolfSSH.
|
|
|
|
find_path(WOLFSSH_INCLUDE_DIR NAMES "wolfssh/ssh.h")
|
|
find_library(WOLFSSH_LIBRARY NAMES "wolfssh" "libwolfssh")
|
|
|
|
if(WOLFSSH_INCLUDE_DIR AND EXISTS "${WOLFSSH_INCLUDE_DIR}/wolfssh/version.h")
|
|
set(_version_regex "#[\t ]*define[\t ]+LIBWOLFSSH_VERSION_STRING[\t ]+\"([^\"]*)\"")
|
|
file(STRINGS "${WOLFSSH_INCLUDE_DIR}/wolfssh/version.h" _version_str REGEX "${_version_regex}")
|
|
string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
|
|
set(WOLFSSH_VERSION "${_version_str}")
|
|
unset(_version_regex)
|
|
unset(_version_str)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WolfSSH
|
|
REQUIRED_VARS
|
|
WOLFSSH_INCLUDE_DIR
|
|
WOLFSSH_LIBRARY
|
|
VERSION_VAR
|
|
WOLFSSH_VERSION
|
|
)
|
|
|
|
if(WOLFSSH_FOUND)
|
|
set(WOLFSSH_INCLUDE_DIRS ${WOLFSSH_INCLUDE_DIR})
|
|
set(WOLFSSH_LIBRARIES ${WOLFSSH_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(WOLFSSH_INCLUDE_DIR WOLFSSH_LIBRARY)
|