432f2fd9ac
- use the same pattern across all Find modules:
- verify if the version header exists before reading it.
- use a single regex per lookup.
- sync regexes between Find modules.
- use generic temporary variable names.
- improve readability.
- make it simpler to transition to new CMake syntax in the future:
```cmake
file(STRINGS "${CARES_INCLUDE_DIR}/ares_version.h" _version_str REGEX "<...>")
unset(_version_str)
set(CARES_VERSION "${CMAKE_MATCH_1}")
```
Ref: https://cmake.org/cmake/help/latest/policy/CMP0159.html#policy:CMP0159
- fix zstd version detection to be CMake 3.7 compatible.
Required 3.9 before this patch, for the `CMAKE_MATCH_<n>` feature.
Follow-up to c5d506e9bb #12200
Follow-up to 4e2f3641f8 #14548
Closes #14572
76 lines
2.4 KiB
CMake
76 lines
2.4 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the wolfssl library
|
|
#
|
|
# Result Variables:
|
|
#
|
|
# WolfSSL_FOUND System has wolfssl
|
|
# WolfSSL_INCLUDE_DIRS The wolfssl include directories
|
|
# WolfSSL_LIBRARIES The wolfssl library names
|
|
# WolfSSL_VERSION Version of wolfssl
|
|
|
|
if(CURL_USE_PKGCONFIG)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(PC_WOLFSSL QUIET "wolfssl")
|
|
endif()
|
|
|
|
find_path(WolfSSL_INCLUDE_DIR NAMES "wolfssl/ssl.h"
|
|
HINTS
|
|
${PC_WOLFSSL_INCLUDEDIR}
|
|
${PC_WOLFSSL_INCLUDE_DIRS}
|
|
)
|
|
|
|
find_library(WolfSSL_LIBRARY NAMES "wolfssl"
|
|
HINTS
|
|
${PC_WOLFSSL_LIBDIR}
|
|
${PC_WOLFSSL_LIBRARY_DIRS}
|
|
)
|
|
|
|
if(PC_WOLFSSL_VERSION)
|
|
set(WolfSSL_VERSION ${PC_WOLFSSL_VERSION})
|
|
elseif(WolfSSL_INCLUDE_DIR AND EXISTS "${WolfSSL_INCLUDE_DIR}/wolfssl/version.h")
|
|
set(_version_regex "#[\t ]*define[\t ]+LIBWOLFSSL_VERSION_STRING[\t ]+\"([^\"]*)\"")
|
|
file(STRINGS "${WolfSSL_INCLUDE_DIR}/wolfssl/version.h" _version_str REGEX "${_version_regex}")
|
|
string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
|
|
set(WolfSSL_VERSION "${_version_str}")
|
|
unset(_version_regex)
|
|
unset(_version_str)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WolfSSL
|
|
REQUIRED_VARS
|
|
WolfSSL_INCLUDE_DIR
|
|
WolfSSL_LIBRARY
|
|
VERSION_VAR
|
|
WolfSSL_VERSION
|
|
)
|
|
|
|
if(WolfSSL_FOUND)
|
|
set(WolfSSL_INCLUDE_DIRS ${WolfSSL_INCLUDE_DIR})
|
|
set(WolfSSL_LIBRARIES ${WolfSSL_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(WolfSSL_INCLUDE_DIR WolfSSL_LIBRARY)
|