9dfdc6ff42
Before this patch, `pkg-config` was used for `UNIX` builds only (with a few exceptions like wolfSSL, libssh, gsasl, libuv). This patch extends `pkg-config` use to all envs except: `MSVC` without vcpkg. Meaning MSVC with vcpkg will now use it. Also mingw on Windows. Also apply the new condition to options where `pkg-config` was used unconditionally (= for all targets). These are: `-DCURL_USE_WOLFSSL=ON`, `-DCURL_USE_LIBSSH=ON`, `-DCURL_USE_GSASL=ON` and `-DCURL_USE_LIBUV=ON` This patch may still cause regressions for cross-builds (e.g. mingw cross-build from Unix) and potentially other cases. If that happens, we recommend using some of these methods to explicitly disable `pkg-config` when using CMake: - CMake option: `-DPKG_CONFIG_EXECUTABLE=` (or `-DPKG_CONFIG_EXECUTABLE=nonexistent` or similar) This is similar to the (curl-specific) `PKG_CONFIG` env for autotools. - export env: `PKG_CONFIG_LIBDIR=` (or `PKG_CONFIG_PATH`, `PKG_CONFIG_SYSROOT_DIR`, or the CMake-specific `PKG_CONFIG`) We may improve control over this in a future patch, also allowing opting in MSVC (without vcpkg). Ref: #14405 Ref: #14408 Ref: #14140 Closes #14483
71 lines
2.1 KiB
CMake
71 lines
2.1 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the nghttp2 library
|
|
#
|
|
# Result Variables:
|
|
#
|
|
# NGHTTP2_FOUND System has nghttp2
|
|
# NGHTTP2_INCLUDE_DIRS The nghttp2 include directories
|
|
# NGHTTP2_LIBRARIES The libraries needed to use nghttp2
|
|
# NGHTTP2_VERSION Version of nghttp2
|
|
|
|
if(NOT MSVC OR VCPKG_TOOLCHAIN)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_search_module(PC_NGHTTP2 "libnghttp2")
|
|
endif()
|
|
|
|
find_path(NGHTTP2_INCLUDE_DIR "nghttp2/nghttp2.h"
|
|
HINTS
|
|
${PC_NGHTTP2_INCLUDEDIR}
|
|
${PC_NGHTTP2_INCLUDE_DIRS}
|
|
)
|
|
|
|
find_library(NGHTTP2_LIBRARY NAMES "nghttp2" "nghttp2_static"
|
|
HINTS
|
|
${PC_NGHTTP2_LIBDIR}
|
|
${PC_NGHTTP2_LIBRARY_DIRS}
|
|
)
|
|
|
|
if(PC_NGHTTP2_VERSION)
|
|
set(NGHTTP2_VERSION ${PC_NGHTTP2_VERSION})
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(NGHTTP2
|
|
FOUND_VAR
|
|
NGHTTP2_FOUND
|
|
REQUIRED_VARS
|
|
NGHTTP2_INCLUDE_DIR
|
|
NGHTTP2_LIBRARY
|
|
VERSION_VAR
|
|
NGHTTP2_VERSION
|
|
)
|
|
|
|
if(NGHTTP2_FOUND)
|
|
set(NGHTTP2_INCLUDE_DIRS ${NGHTTP2_INCLUDE_DIR})
|
|
set(NGHTTP2_LIBRARIES ${NGHTTP2_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(NGHTTP2_INCLUDE_DIRS NGHTTP2_LIBRARIES)
|