699ac9430c
Via these variables, as lists: - `CURL_SUPPORTED_PROTOCOLS` - `CURL_SUPPORTED_FEATURES` As individual flags: - `CURL_SUPPORTS_<protocol/feature>` = `TRUE` Also: - set `CURL_VERSION_STRING` which was missing when using `find_package(CURL CONFIG)` or `find_package(CURL NO_MODULE)`. - set `CURL_<prototol/feature>_FOUND` for compatibility. - show full list of missing but required `COMPONENTS`. Assisted-by: Derek Huang Fixes #15854 Closes #15858
78 lines
2.7 KiB
CMake
78 lines
2.7 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
@PACKAGE_INIT@
|
|
|
|
if(UNIX OR VCPKG_TOOLCHAIN OR (MINGW AND NOT CMAKE_CROSSCOMPILING)) # Keep in sync with root CMakeLists.txt
|
|
set(_curl_use_pkgconfig_default ON)
|
|
else()
|
|
set(_curl_use_pkgconfig_default OFF)
|
|
endif()
|
|
option(CURL_USE_PKGCONFIG "Enable pkg-config to detect @PROJECT_NAME@ dependencies" ${_curl_use_pkgconfig_default})
|
|
|
|
include(CMakeFindDependencyMacro)
|
|
if("@USE_OPENSSL@")
|
|
find_dependency(OpenSSL "@OPENSSL_VERSION_MAJOR@")
|
|
endif()
|
|
if("@HAVE_LIBZ@")
|
|
find_dependency(ZLIB "@ZLIB_VERSION_MAJOR@")
|
|
endif()
|
|
|
|
include("${CMAKE_CURRENT_LIST_DIR}/@TARGETS_EXPORT_NAME@.cmake")
|
|
|
|
# Alias for either shared or static library
|
|
if(NOT TARGET @PROJECT_NAME@::libcurl)
|
|
add_library(@PROJECT_NAME@::libcurl ALIAS @PROJECT_NAME@::@LIB_SELECTED@)
|
|
endif()
|
|
|
|
# For compatibility with CMake's FindCURL.cmake
|
|
set(CURL_VERSION_STRING "@CURLVERSION@")
|
|
set(CURL_LIBRARIES @PROJECT_NAME@::libcurl)
|
|
set_and_check(CURL_INCLUDE_DIRS "@PACKAGE_CMAKE_INSTALL_INCLUDEDIR@")
|
|
|
|
set(CURL_SUPPORTED_PROTOCOLS "@CURL_SUPPORTED_PROTOCOLS_LIST@")
|
|
set(CURL_SUPPORTED_FEATURES "@CURL_SUPPORTED_FEATURES_LIST@")
|
|
|
|
foreach(_item IN LISTS CURL_SUPPORTED_PROTOCOLS CURL_SUPPORTED_FEATURES)
|
|
set(CURL_SUPPORTS_${_item} TRUE)
|
|
endforeach()
|
|
|
|
set(_missing_req "")
|
|
foreach(_item IN LISTS CURL_FIND_COMPONENTS)
|
|
if(CURL_SUPPORTS_${_item})
|
|
set(CURL_${_item}_FOUND TRUE)
|
|
elseif(CURL_FIND_REQUIRED_${_item})
|
|
list(APPEND _missing_req ${_item})
|
|
endif()
|
|
endforeach()
|
|
|
|
if(_missing_req)
|
|
string(REPLACE ";" " " _missing_req "${_missing_req}")
|
|
if(CURL_FIND_REQUIRED)
|
|
message(FATAL_ERROR "CURL: missing required components: ${_missing_req}")
|
|
endif()
|
|
unset(_missing_req)
|
|
endif()
|
|
|
|
check_required_components("@PROJECT_NAME@")
|