dc874d4369
- cmp-config.pl: add remaining exceptions. Sort list. - drop unused `HAVE_SYS_WAIT_H`. Follow-up to50def7c881#13249 - drop unused `HAVE_FCHMOD`. Follow-up to03cb1ff4d6#12395 - autotools: stop promoting variables to macros: `USE_NGTCP2_CRYPTO_*`, `USE_NGTCP2_H3`, `USE_OPENSSL_H3`, `HAVE_LIBRESSL`. They are not used in the source. - cmake: drop unused `HAVE_O_NONBLOCK`, `HAVE_DISABLED_NONBLOCKING`. - lib: drop `NEED_MALLOC_H`. It was used in manual-build cases for Amiga/MS-DOS/Windows/WinCE, but never by autotools/cmake, thus apparently unnecessary. - lib: drop unused `NEED_MEMORY_H`. - lib: simplify classic mac feature guards, drop `HAVE_EXTRA_STRICMP_H` and `HAVE_EXTRA_STRDUP_H`. - autotools: drop unused `HAVE_GETHOSTBYNAME` detection. - autotools: drop unused OpenSSL feature tests: `HAVE_ERR_H`, `HAVE_PEM_H`, `HAVE_RSA_H` - autotools: drop unused OpenSSL feature tests: `HAVE_X509_H`, `HAVE_CRYPTO_H`, `HAVE_SSL_H`. They performed a fallback check when the primary check missed `openssl/x509.h`. Though if any other prefixed headers were found, OpenSSL is already assumed detected. The fallback check was looking for 3 unprefixed OpenSSL headers, and if all found, marked OpenSSL found internally, but did not promote it to `curl_config.h` via `USE_OPENSSL`. Meaning it either didn't do anything or may have continued with an inconsistent state. Added ind99c20f628(2008) At the time, there was an extra `AC_DEFINE(USE_SSLEAY, 1 ...` logic after this code, which kicked in in the fallback case, but that code was deleted in709cf76f6b(2015) Follow-up to709cf76f6b- autotools: drop `AC_SUBST()` where the value is explicitly set anyway and the macro is unused. - autotools: replace `AC_SUBST(VAR, 1)` with local variable assigments, where the `@VAR@` macro is unused. Also dedupe the local variable if there was a parallel one used for the same purpose. - autotools: drop local feature variables that were never used. - autotools: drop unused `CURL_CHECK_OPTION_NTLM_WB`, `CURL_CHECK_NTLM_WB`. Also stop setting unused `NTLM_WB_ENABLED` macro for VMS. Follow-up to50def7c881#13249 - autotools: drop unused `PKGADD_*`. Follow-up tobae0d473f5#3331 - autotools: drop unused `CURL_NETWORK_LIBS`. Follow-up to3af75e18d6#14697 Closes #15577
117 lines
3.6 KiB
Plaintext
117 lines
3.6 KiB
Plaintext
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
#***************************************************************************
|
|
|
|
dnl ----------------------------------------------------
|
|
dnl check for mbedTLS
|
|
dnl ----------------------------------------------------
|
|
AC_DEFUN([CURL_WITH_MBEDTLS], [
|
|
|
|
if test "x$OPT_MBEDTLS" != xno; then
|
|
_cppflags=$CPPFLAGS
|
|
_ldflags=$LDFLAGS
|
|
_ldflagspc=$LDFLAGSPC
|
|
ssl_msg=
|
|
|
|
if test X"$OPT_MBEDTLS" != Xno; then
|
|
|
|
if test "$OPT_MBEDTLS" = "yes"; then
|
|
OPT_MBEDTLS=""
|
|
fi
|
|
|
|
if test -z "$OPT_MBEDTLS" ; then
|
|
dnl check for lib first without setting any new path
|
|
|
|
AC_CHECK_LIB(mbedtls, mbedtls_havege_init,
|
|
dnl libmbedtls found, set the variable
|
|
[
|
|
AC_DEFINE(USE_MBEDTLS, 1, [if mbedTLS is enabled])
|
|
MBEDTLS_ENABLED=1
|
|
USE_MBEDTLS="yes"
|
|
ssl_msg="mbedTLS"
|
|
test mbedtls != "$DEFAULT_SSL_BACKEND" || VALID_DEFAULT_SSL_BACKEND=yes
|
|
], [], -lmbedx509 -lmbedcrypto)
|
|
fi
|
|
|
|
addld=""
|
|
addlib=""
|
|
addcflags=""
|
|
mbedtlslib=""
|
|
|
|
if test "x$USE_MBEDTLS" != "xyes"; then
|
|
dnl add the path and test again
|
|
addld=-L$OPT_MBEDTLS/lib$libsuff
|
|
addcflags=-I$OPT_MBEDTLS/include
|
|
mbedtlslib=$OPT_MBEDTLS/lib$libsuff
|
|
|
|
LDFLAGS="$LDFLAGS $addld"
|
|
LDFLAGSPC="$LDFLAGSPC $addld"
|
|
if test "$addcflags" != "-I/usr/include"; then
|
|
CPPFLAGS="$CPPFLAGS $addcflags"
|
|
fi
|
|
|
|
AC_CHECK_LIB(mbedtls, mbedtls_ssl_init,
|
|
[
|
|
AC_DEFINE(USE_MBEDTLS, 1, [if mbedTLS is enabled])
|
|
MBEDTLS_ENABLED=1
|
|
USE_MBEDTLS="yes"
|
|
ssl_msg="mbedTLS"
|
|
test mbedtls != "$DEFAULT_SSL_BACKEND" || VALID_DEFAULT_SSL_BACKEND=yes
|
|
],
|
|
[
|
|
CPPFLAGS=$_cppflags
|
|
LDFLAGS=$_ldflags
|
|
LDFLAGSPC=$_ldflagspc
|
|
], -lmbedx509 -lmbedcrypto)
|
|
fi
|
|
|
|
if test "x$USE_MBEDTLS" = "xyes"; then
|
|
AC_MSG_NOTICE([detected mbedTLS])
|
|
check_for_ca_bundle=1
|
|
|
|
LIBS="-lmbedtls -lmbedx509 -lmbedcrypto $LIBS"
|
|
|
|
if test -n "$mbedtlslib"; then
|
|
dnl when shared libs were found in a path that the run-time
|
|
dnl linker doesn't search through, we need to add it to
|
|
dnl CURL_LIBRARY_PATH to prevent further configure tests to fail
|
|
dnl due to this
|
|
if test "x$cross_compiling" != "xyes"; then
|
|
CURL_LIBRARY_PATH="$CURL_LIBRARY_PATH:$mbedtlslib"
|
|
export CURL_LIBRARY_PATH
|
|
AC_MSG_NOTICE([Added $mbedtlslib to CURL_LIBRARY_PATH])
|
|
fi
|
|
fi
|
|
dnl FIXME: Enable when mbedTLS was detected via pkg-config
|
|
if false; then
|
|
LIBCURL_PC_REQUIRES_PRIVATE="$LIBCURL_PC_REQUIRES_PRIVATE mbedtls"
|
|
fi
|
|
fi
|
|
|
|
fi dnl mbedTLS not disabled
|
|
|
|
test -z "$ssl_msg" || ssl_backends="${ssl_backends:+$ssl_backends, }$ssl_msg"
|
|
fi
|
|
|
|
])
|